RumusHitung.com – Halo guys, bagaimana kabarnya? Semoga masih semangat yaa.. Kali ini rumushitung akan melanjutkan pembahasan mengenai rumus Excel. Pada pembahasan sebelumnya, sobat telah mempelajari tentang gabungan rumus Average pada Excel dan pengelompokan data (grouping). Selanjutnya, kita akan bahas mengenai gabungan rumus Rank pada Excel.
Ada 6 contoh gabungan rumus Rank pada Excel :
1) Contoh fungsi RANK (Peringkat)
2) Beri RANK rumus IF
3) Hasil RANK dari perlombaan
4) Beri RANK nilai menurut bulan
5) RANK dengan urut akhiran (sufiks ordinal)
6) RANK tanpa ikatan
Contents
Contoh Fungsi RANK (Peringkat)
Untuk memberi peringkat sekumpulan nilai numerik, di mana nilai tertinggi diberi peringkat #1, bisa menggunakan fungsi RANK. Pada contoh yang diperlihatkan, rumus di sel D3 kemudian disalin ke bawah :
=RANK(C3;C$3:C$10)
Gunakan fungsi RANK untuk memberi peringkat nilai numerik.
RANK memiliki dua mode operasi :
a. nilai peringkat dengan nilai terbesar # 1 (urutan = 0)
b. nilai peringkat dengan nilai terendah # 1 (urutan = 1)
Pada kasus ini, akan memeringkat skor tes, jadi nilai tertinggi harus peringkat #1, jadi harus menghilangkan argumen urutan, yang defaultnya nol :
=RANK(C3;C$3:C$10)
Rumus berikut, yang menyertakan urutan diatur ke nol, adalah setara :
=RANK(C3;C$3:C$10;0)
Beri RANK Rumus IF
Untuk memberi peringkat item dalam daftar menggunakan satu atau beberapa kriteria, gunakan fungsi COUNTIFS. Dalam contoh yang ditampilkan, rumus dalam E3 :
=COUNTIFS(C$3:C$12;C3;D$3:D$12;”>”&D3)+1
Hasilnya adalah peringkat untuk setiap orang dalam kelompoknya sendiri. Catatan : meskipun data diurutkan berdasarkan grup di tangkapan layar, rumus akan berfungsi dengan baik dengan data yang tidak diurutkan.
Hasil RANK dari Perlombaan
Untuk menentukan peringkat sekumpulan waktu perlombaan, di mana waktu terendah (tercepat) berada di peringkat #1, Anda dapat menggunakan fungsi PERINGKAT. Dalam contoh yang diperlihatkan, rumus di sel D3 :
=RANK(C3;C$3:C$10;1)
Gunakan fungsi RANK untuk memberi peringkat nilai numerik. RANK memiliki dua mode operasi :
a. nilai peringkat sehingga nilai terbesar diberi peringkat # 1 (urutan = 0)
b. nilai peringkat sehingga nilai terkecil adalah # 1 (urutan = 1)
Dalam hal ini, akan memeringkat waktu perlombaan. Nilai terendah / tercepat harus berada di peringkat #1, jadi harus menetapkan argumen urutan ke 1 :
=RANK(C3;C$3:C$10;1)
Beri RANK Nilai Menurut Bulan
Untuk menampilkan daftar nama, diberi peringkat berdasarkan nilai numerik, Anda dapat menggunakan sekumpulan rumus berdasarkan LARGE, INDEX, MATCH, dengan bantuan dari fungsi TEXT. Pada contoh yang ditunjukkan, rumus di G3 :
=LARGE(IF(TEXT($C$3:$C$15;”mmmm”)=G$2;$D$3:$D$15);$F3)
Dan di sel G8 adalah :
=INDEX($B$3:$B$15;MATCH(1;($D$3:$D$15=G3)*(TEXT($C$3:$C$15;”mmmm”)=G$7);0))
Contoh ini disiapkan dalam dua bagian untuk kejelasan : (1) rumus untuk menentukan 3 jumlah teratas untuk setiap bulan
(2) rumus untuk mengambil nama klien untuk masing-masing dari 3 jumlah bulanan teratas
Perhatikan bahwa tidak ada peringkat sebenarnya dalam data sumber. Sebagai gantinya, gunakan fungsi LARGE untuk bekerja secara langsung dengan jumlah. Pendekatan lain adalah menambahkan peringkat ke data sumber dengan fungsi RANK, dan menggunakan nilai peringkat untuk mengambil nama klien.
RANK dengan Urut Akhiran (Sufiks Ordinal)
Untuk menambahkan sufiks ordinal ke angka (misalnya, ke-1, ke-2, ke-3, dll.) Anda dapat menggunakan rumus berdasarkan fungsi CHOOSE untuk menetapkan sufiks.
Dalam contoh yang ditunjukkan, rumus di C3 adalah :
=CHOOSE(B3;”st”;”nd”;”rd”;”th”;”th”;”th”;”th”;”th”;”th”;”th”)
Nomor urut mewakili posisi atau peringkat dalam urutan berurutan. Biasanya ditulis menggunakan akhiran angka + huruf : 1, 2, 3, dll.
Untuk mendapatkan sufiks ordinal untuk sekumpulan kecil angka, gunakan fungsi CHOOSE seperti :
=CHOOSE(B3;”st”;”nd”;”rd”;”th”;”th”;”th”;”th”;”th”;”th”;”th”)
Di sini CHOOSE mengambil nomor dari kolom B dan menggunakan nomor itu sebagai indeks untuk mengambil sufiks yang tepat.
Formula universal
Dengan rentang angka yang lebih besar, tidak praktis untuk terus menambahkan nilai ke CHOOSE. Jika demikian, Anda dapat beralih ke rumus yang lebih rumit yang menggunakan fungsi MOD :
=IF(AND(MOD(ABS(A1);100)>10;MOD(ABS(A1);100)<14);”th”;
CHOOSE(MOD(ABS(A1);10)+1;”th”;”st”;”nd”;”rd”;”th”;”th”;”th”;”th”;”th”;”th”))
Rumus ini pertama kali menggunakan MOD dengan AND untuk “menjebak” kasus bilangan seperti 11, 12, 13, 111, 112, 113, dll. Yang memiliki sufiks non-standar dengan selalu “th”. Semua angka lainnya menggunakan 10 nilai sufiks di dalam CHOOSE.
Fungsi ABS digunakan untuk menangani bilangan negatif maupun bilangan positif.
Gabungkan sufiks dengan angka
Gabungkan sufiks secara langsung menggunakan salah satu rumus di atas. Misalnya untuk menambahkan sufiks ordinal ke angka 1-10 di A1.
=A1&CHOOSE(A1;”st”;”nd”;”rd”;”th”;”th”;”th”;”th”;”th”;”th”;”th”)
Tetapi ketahuilah bahwa melakukan hal itu akan mengubah angka menjadi nilai teks.
RANK Tanpa Ikatan
Untuk menetapkan peringkat tanpa ikatan, gunakan rumus yang didasarkan pada fungsi RANK dan COUNTIF. Pada contoh yang ditunjukkan, rumus dalam E3 seperti :
=RANK(C3;C$3:C$10)+COUNTIF($C$3:C3;C3)-1
Rumus ini memutuskan hubungan dengan pendekatan sederhana :
seri pertama dalam daftar “menang” dan diberi peringkat yang lebih tinggi. Bagian pertama rumus menggunakan fungsi RANK secara normal :
=RANK(C3;C$3:C$10)
Rank menghasilkan peringkat yang dihitung, yang akan menyertakan ikatan ketika nilai yang diberi peringkat menyertakan duplikat. Perhatikan bahwa fungsi RANK dengan sendirinya akan menetapkan peringkat yang sama untuk nilai duplikat, dan melewatkan nilai peringkat berikutnya. Bisa dilihat pada contoh di atas di kolom Rank 1, baris 6 dan 7 di lembar kerja.
Bagian kedua dari rumus memutuskan ikatan dengan COUNTIF :
COUNTIF($C$3:C3;C3)-1
Demikian penjelasan mengenai gabungan rumus Rank pada Excel, semoga bermanfaat. Sekian terima kasih.