RumusHitung.com – Halo guys, bagaimana kabarnya? Semoga masih semangat yaa.. Kali ini rumushitung akan melanjutkan pembahasan mengenai rumus Excel. Pada pembahasan sebelumnya, sobat telah mempelajari tentang gabungan rumus Average pada Excel, pengelompokan data (grouping), gabungan rumus Rank pada Excel, dan seri tanggal (date series) pada Excel. Selanjutnya, kita akan bahas mengenai gabungan rumus Random pada Excel.
Ada 9 contoh gabungan rumus Random, antara lain :
1) Tanggal acak antara dua tanggal
2) Nomor acak antara dua nomor
3) Nomor acak dari serangkaian opsi tetap
4) Kemungkinan pembobotan nomor acak
5) Nilai teks acak
6) Waktu acak pada interval tertentu
7) Nilai acak dari daftar atau tabel
8) Tetapkan data secara acak ke kelompok
9) Tetapkan orang secara acak ke dalam kelompok
Contents
- 1 Tanggal Acak antara Dua Tanggal
- 2 Nomor Acak antara Dua Nomor
- 3 Nomor Acak dari Serangkaian Opsi Tetap
- 4 Kemungkinan Pembobotan Nomor Acak
- 5 Nilai Teks Acak
- 6 Waktu Acak pada Interval Tertentu
- 7 Nilai Acak dari Daftar atau Tabel
- 8 Tetapkan Data Secara Acak ke Kelompok
- 9 Tetapkan Orang Secara Acak ke Dalam Kelompok
Tanggal Acak antara Dua Tanggal
Untuk menghasilkan tanggal acak antara dua tanggal, gunakan fungsi RANDBETWEEN, bersama dengan fungsi DATE. Pada contoh yang ditunjukkan, rumus di sel B3 :
=RANDBETWEEN(DATE(2016;1;1);DATE(2016;12;31))
Rumus ini kemudian disalin dari B3 ke B9. Hasilnya adalah tanggal acak antara 1 Jan 2016 dan 31 Des 2016 (tanggal acak pada tahun 2016).
Fungsi RANDBETWEEN mengambil dua angka, angka bawah dan atas, dan menghasilkan bilangan bulat acak di antaranya. Tanggal di Excel adalah nomor seri, sehingga fungsi DATE dapat digunakan untuk membuat angka bawah dan angka atas. RANDBETWEEN kemudian menghasilkan angka yang berada di antara dua nilai tanggal tersebut.
Hari kerja acak
Untuk membuat hari kerja acak, tambahkan fungsi WORKDAY seperti :
=WORKDAY(RANDBETWEEN(date1;date2)-1;1)
Fungsi WORKDAY memastikan bahwa tanggal yang dihasilkan adalah hari kerja, dan bukan akhir pekan (opsional) hari libur. Perhatikan bahwa WORKDAY akan mengalihkan tanggal yang jatuh pada akhir pekan atau hari libur ke hari kerja berikutnya, sehingga kemungkinan bisa melihat tanggal yang melampaui argumen date2.
Nomor Acak antara Dua Nomor
Untuk menghasilkan nomor acak antara dua nomor, gunakan fungsi RANDBETWEEN. Pada contoh yang ditunjukkan, rumus di sel B3 :
=RANDBETWEEN(1;100)
Rumus ini kemudian disalin ke bawah dari B3 ke B9. Hasilnya adalah angka acak antara 1-100.
Perhatikan bahwa fungsi RANDBETWEEN akan menghasilkan angka baru setiap kali perubahan dipicu pada lembar kerja. Itu termasuk semua pengeditan pada lembar kerja juga hanya membuka buku.
Nomor Acak dari Serangkaian Opsi Tetap
Untuk dengan cepat mengisi rentang sel dengan nomor acak dari sekumpulan opsi tetap (yaitu 25, 50, 75, 100), gunakan rumus berdasarkan fungsi CHOOSE dan RANDBETWEEN.
Pada contoh yang ditunjukkan, rumus di sel B2 :
=CHOOSE(RANDBETWEEN(1;4);25;50;75;100)
Yang menghasilkan nomor acak dari nomor yang disediakan.
Kemungkinan Pembobotan Nomor Acak
Untuk menghasilkan nomor acak, berbobot dengan kemungkinan tertentu, gunakan tabel pembantu bersama dengan rumus yang didasarkan pada fungsi RAND dan MATCH.
Pada contoh yang ditunjukkan, rumus di sel F3 :
=MATCH(RAND();D$3:D$8)
Rumus ini bergantung pada tabel pembantu yang terlihat pada rentang B2:D8. Kolom B berisi enam angka yang diinginkan sebagai hasil akhir. Kolom C berisi bobot kemungkinan yang diterapkan untuk setiap angka, dimasukkan sebagai persentase. Kolom D berisi kemungkinan kumulatif, dibuat dengan rumus di sel D3, kemudian disalin ke bawah :
=SUM(D3;C3)
Perhatikan, dengan sengaja menggeser kemungkinan kumulatif ke bawah satu per satu baris, sehingga nilai di sel D3 adalah nol. Hal ini untuk memastikan MATCH bisa menemukan posisi untuk semua nilai hingga nol seperti yang dijelaskan di bawah.
Untuk menghasilkan nilai acak, menggunakan kemungkinan tertimbang di tabel pembantu, F3 berisi rumus seperti ini, kemudian disalin ke bawah :
=MATCH(RAND();D$3:D$8)
Nilai teks berbobot acak
Untuk menghasilkan nilai teks berbobot acak (yaitu nilai non-numerik), masukkan nilai teks dalam rentang B3:B8, lalu menambahkan INDEX untuk menghasilkan nilai dalam rentang tersebut berdasarkan posisi yang dihasilkan oleh MATCH.
=INDEX($B$3:$B$8;MATCH(RAND();D$3:D$8))
Nilai Teks Acak
Untuk mengisi rentang sel secara cepat dengan nilai teks acak, gunakan rumus yang didasarkan pada fungsi CHOOSE dan RANDBETWEEN.
Pada contoh yang ditunjukkan, rumus di sel C3 :
=CHOOSE(RANDBETWEEN(1;4);”Merah”;”Biru”;”Hijau”;”Ungu”)
Yang menghasilkan warna acak dari nilai yang diberikan.
Fungsi CHOOSE menyediakan kerangka kerja untuk rumus ini. CHOOSE mengambil satu nilai numerik sebagai argumen pertamanya (index_number) dan menggunakan nomor ini untuk memilih dan menghasilkan salah satu nilai yang diberikan sebagai argumen berikutnya berdasarkan indeks numeriknya.
Hal ini, ada empat nilai yang digunakan : Merah, Biru, Hijau, dan Ungu. Jadi, kami butuh memberi CHOOSE nomor 1 dan 4.
Untuk menghasilkan nomor ini, gunakan RANDBETWEEN yang menghasilkan bilangan bulat acak antara nilai bawah dan atas. Karena hanya bekerja dengan 4 nilai di CHOOSE, satu yang disediakan untuk angka terbawah dan 4 untuk angka atas.
Ketika rumus ini disalin, maka akan menghasilkan salah satu dari 4 warna.
Waktu Acak pada Interval Tertentu
Untuk menghasilkan waktu acak pada interval tertentu, gunakan fungsi RAND dengan fungsi FLOOR. Pada contoh yang ditampilkan, rumus di B3 :
=FLOOR(RAND();”0:15”)
Yang menghasilkan waktu acak dengan interval 15 menit.
Pengaturan waktu atas dan bawah
Jika ingin membatasi jam yang digunakan oleh RAND, gunakan rumus umum ini yang RAND untuk menghasilkan angka antara nilai atas dan bawah.
=RAND()*(atas-bawah)+bawah
Karena Excel bisa mengenali nilai waktu, dapat diperoleh waktu antara jam 8 pagi dan 12 siang, dengan rumus seperti :
=RAND()*(“12:00”-“8:00”)+”8:00”
Catatan : rumus di atas bersifat umum dan akan berfungsi dengan angka lain juga, bukan hanya waktu.
Nilai Acak dari Daftar atau Tabel
Untuk memperoleh nilai acak dari tabel atau daftar pada Excel, bisa menggunakan fungsi INDEX dengan bantuan dari fungsi RANDBETWEEN dan ROWS.
Pada contoh yang ditunjukkan, rumus di sel G7 :
=INDEX(data,RANDBETWEEN(1,ROWS(data)),1)
Dengan B5:E104 dibuat menjadi data.
Untuk menarik nilai acak dari daftar atau tabel, dibutuhkan nomor baris acak. Untuk itu, gunakan fungsi RANDBETWEEN yang menghasilkan bilangan bulat acak antara dua nilai yang diberikan – nilai atas dan nilai yang lebih rendah.
Untuk nilai yang lebih rendah, gunakan angka 1, dan untuk nilai atas gunakan fungsi ROWS untuk menghitung total baris dalam tabel atau daftar :
=RANDBETWEEN(1,ROWS(data))
RANDBETWEEN akan menghasilkan angka acak antara 1 dan jumlah baris dalam data, dan hasil ini dimasukkan ke dalam fungsi INDEX untuk argumen baris. Untuk argumen kolom, cukup gunakan 1 karena yang diinginkan nama dari kolom pertama.
Jadi, dengan asumsi bahwa RANDBETWEEN menghasilkan 7 (seperti pada contoh), rumus tersebut dikurangi menjadi :
Yang menghasilkan nama “Tim Moore”, di baris 7 tabel.
Perhatikan bahwa RANDBETWEEN menghitung ulang setiap kali lembar kerja diubah atau dibuka.
Tetapkan Data Secara Acak ke Kelompok
Untuk secara acak sesuatu ke kelompok, gunakan fungsi RANDBETWEEN dengan fungsi CHOOSE. Pada contoh yang ditampilkan, rumus di sel F3 :
=CHOOSE(RANDBETWEEN(1;3);”A”;”B”;”C”)
Ketika disalin ke bawah kolom, rumus ini akan menghasilkan kelompok acak (A, B, atau C) untuk setiap orang dalam daftar.
Catatan : ini adalah pendekatan acak yang memungkinkan kelompok dengan ukuran yang berbeda.
Penghitungan ulang
Ketahuilah bahwa RANDBETWEEN akan menghitung ulang setiap kali ada perubahan apapun pada buku kerja atau bahkan ketika buku kerja dibuka. Setelah memiliki sekumpulan tugas acak, mungkin sebaiknya harus menyalin dan menempelkan rumus sebagai nilai untuk mencegah perubahan lebih lanjut.
Tetapkan Orang Secara Acak ke Dalam Kelompok
Untuk menetapkan orang secara acak ke dalam kelompok, grup atau tim dengan ukuran tertentu, gunakan kolom pembantu dengan nilai yang dihasilkan oleh fungsi RAND, bersama dengan rumus yang didasarkan pada fungsi RANK dan ROUNDUP. Pada contoh yang ditunjukkan, rumus di sel D3 :
=ROUNDUP(RANK(C3;C$3:C$14)/G$5;0)
Versi CEILING
Fungsi CEILING bisa digunakan sebagai pengganti ROUNDUP. Seperti fungsi ROUNDUP, CEILING juga membulatkan namun alih-alih membulatkan ke sejumlah tempat desimal tertentu, CEILING membulatkan ke kelipatan tertentu.
=CEILING(RANK(C3;C$3:C$14)/G$5;1)
Demikian penjelasan mengenai gabungan rumus Random, semoga bermanfaat. Sekian terima kasih.